Gording versterken berekenen

Formulas:

• h_a = if(helling > 0 && helling < 90, helling * 3.14159265 / 180, 0)
  
• h_cos = 1 - h_a * h_a / 2 + h_a * h_a * h_a * h_a / 24 - h_a * h_a * h_a * h_a * h_a * h_a / 720
  
• h_mu = if(helling <= 30, 0.8, if(helling < 60, 0.8 * (60 - helling) / 30, 0))
  
• h_E = if(hout == 'c24', 11000, if(hout == 'c16', 8000, 9000))
  
• h_rho = if(hout == 'c24', 420, if(hout == 'c16', 370, 380))
  
• h_b = if(hoh > 0, hoh, 0)
  
• h_L = if(overspanning > 0, overspanning * 1000, 0)
  
• h_q0 = h_b * (0.7 + h_mu * 0.7 * h_cos + if(extra_last > 0, extra_last, 0))
  
• h_g1 = b1 * h1 / 1000000 * h_rho * 9.81 / 1000
  
• h_g2 = b2 * h2 / 1000000 * h_rho * 9.81 / 1000
  
• h_I1 = b1 * h1 * h1 * h1 / 12
  
• h_I2 = b2 * h2 * h2 * h2 / 12
  
• h_k = 5 * h_L * h_L * h_L * h_L / (384 * h_E)
  
• h_w1 = if(h_I1 > 0, h_k * (h_q0 + h_g1) / h_I1, 0)
  
• h_w2 = if(h_I1 + h_I2 > 0, h_k * (h_q0 + h_g1 + h_g2) / (h_I1 + h_I2), 0)
  
• belasting = round(h_q0 + h_g1, 2)
  Pannendak met dakplaten 0,70 kN/m², sneeuw 0,7 × vormfactor (0,8 tot 30°, daarna aflopend tot 0 bij 60°), extra gewicht en de gording zelf.
• stijfheid = if(h_I1 > 0, concat(format(round((h_I1 + h_I2) / h_I1, 1), '0.#'), ' keer zo stijf'), '-')
  Traagheidsmoment I = b × h³ / 12 van beide balken opgeteld. Een twee keer zo hoge balk is acht keer zo stijf.
• doorbuiging_voor = round(h_w1, 0)
  w = 5 × q × L⁴ / (384 × E × I), zonder kruip.
• doorbuiging_na = round(h_w2, 0)
  
• grens = round(h_L / 250, 0)
  De grens die constructeurs bij gordingen aanhouden.
• oordeel = if(h_w1 <= h_L / 250, concat('De gording zelf voldoet al: ', format(round(h_w1, 0), '0.#'), ' mm is minder dan ', format(round(h_L / 250, 0), '0.#'), ' mm.'), if(h_w2 <= h_L / 250, concat('Met de extra balk voldoet het: ', format(round(h_w2, 0), '0.#'), ' mm tegen ', format(round(h_L / 250, 0), '0.#'), ' mm toegestaan.'), concat('Ook met de extra balk te slap: ', format(round(h_w2, 0), '0.#'), ' mm tegen ', format(round(h_L / 250, 0), '0.#'), ' mm. Kies een hogere balk.')))
  
• advies = if(gemeten > 2 * h_w1 && gemeten > h_L / 250, 'Je meet veel meer doorbuiging dan de berekening verklaart. Laat een constructeur kijken: misschien is er een steunpunt of dragende wand weggehaald, of is het hout aangetast.', if(situatie == 'dakkapel', 'Een dakkapel geeft puntlasten die deze tool niet meeneemt en vraagt een raveling: laat de gording en de raveling door een constructeur rekenen.', 'Stempel de gording eerst op tot hij recht ligt, zet de extra balk er met de bolle kant naar boven tegen en verbind ze over de hele lengte stevig met elkaar. Laat de nieuwe balk op dezelfde muren of spanten rusten.'))
  

Berekening informatie

Op jouw website?

<script src="https://ikbenbint.nl/widget.js"
  data-berekening="gording-versterken-berekenen">
</script>