Extra aflossen hypotheek berekenen

Formulas:

• h_n = if(rest > 0, ceil(rest * 12 - 0.0001), 0)
  
• h_r = rente / 1200
  
• h_r2 = if(rente - korting > 0, (rente - korting) / 1200, 0)
  
• h_g = if(h_n > 0, exp(h_n * ln(1 + h_r)), 1)
  
• h_g2 = if(h_n > 0, exp(h_n * ln(1 + h_r2)), 1)
  
• h_S2 = if(schuld - extra > 0, schuld - extra, 0)
  
• h_A0 = if(h_n <= 0, 0, if(h_r > 0, schuld * h_r * h_g / (h_g - 1), schuld / h_n))
  
• h_L0 = if(h_n > 0, schuld / h_n + schuld * h_r, 0)
  
• maand_nu = round(if(vorm == 'lineair', h_L0, h_A0), 0)
  Bruto, over je resterende looptijd (bij lineair: deze maand).
• h_A2 = if(h_n <= 0, 0, if(h_r2 > 0, h_S2 * h_r2 * h_g2 / (h_g2 - 1), h_S2 / h_n))
  
• h_x = if(h_A0 > 0, 1 - h_S2 * h_r2 / h_A0, 0)
  
• h_n2 = if(h_S2 <= 0, 0, if(h_r2 > 0, if(h_x > 0, ceil(0 - ln(h_x) / ln(1 + h_r2) - 0.0001), h_n), if(h_A0 > 0, ceil(h_S2 / h_A0 - 0.0001), 0)))
  
• h_n2l = if(h_n > 0 && schuld > 0, ceil(h_S2 / (schuld / h_n) - 0.0001), 0)
  
• maand_nieuw = round(if(h_S2 <= 0 || h_n <= 0, 0, if(vorm == 'lineair', if(keuze == 'maandlast', h_S2 / h_n + h_S2 * h_r2, schuld / h_n + h_S2 * h_r2), if(keuze == 'maandlast', h_A2, maand_nu))), 0)
  
• looptijd_nieuw = round(if(keuze == 'looptijd', if(vorm == 'lineair', h_n2l, h_n2), h_n) / 12, 1)
  
• eerder = round(if(keuze == 'looptijd', (h_n - if(vorm == 'lineair', h_n2l, h_n2)) / 12, 0), 1)
  
• h_ri_oud = h_r * schuld * (h_n + 1) / 2
  
• h_ri_new = if(h_n <= 0, 0, if(keuze == 'maandlast', h_r2 * h_S2 * (h_n + 1) / 2, h_r2 * (schuld / h_n) * h_n2l * (h_n2l + 1) / 2 - h_r2 * (schuld / h_n * h_n2l - h_S2) * h_n2l))
  
• h_tot_oud = h_A0 * h_n
  
• h_tot_new = if(keuze == 'maandlast', h_A2 * h_n, h_A0 * h_n2)
  
• rentebesparing = round(if(h_n <= 0, 0, if(vorm == 'lineair', h_ri_oud - h_ri_new, h_tot_oud - h_tot_new - extra)), 0)
  Zoveel minder rente betaal je in totaal, bruto.
• netto_besparing = round(rentebesparing * (1 - tarief / 100), 0)
  Na de renteaftrek die je misloopt.
• rendement = if(extra > 0, round(rente * (1 - tarief / 100), 2), 0)
  Extra aflossen levert je netto ongeveer je hypotheekrente na aftrek op. Vergelijk dat met je spaarrente.
• ltv_oud = if(waarde > 0, round(schuld / waarde * 100, 1), 0)
  
• ltv_nieuw = if(waarde > 0, round(h_S2 / waarde * 100, 1), 0)
  Komt je LTV onder een grens van je bank (vaak per 10%), dan kan je rente omlaag.
• boete_deel = round(if(extra > vrij, extra - vrij, 0), 0)
  Over dit deel kan je bank boeterente vragen als je rente nog vaststaat.
• h_bt = if(boete_deel > 0, concat(' Let op: ', concat('€ ', format(round(boete_deel,0), '0.#')), ' valt buiten je boetevrije ruimte.'), '')
  
• oordeel = if(schuld <= 0 || h_n <= 0 || extra <= 0, 'Vul je schuld, looptijd en extra aflossing in.', concat(if(keuze == 'maandlast', concat('Je maandlast daalt van ', concat('€ ', format(round(maand_nu,0), '0.#')), ' naar ', concat('€ ', format(round(maand_nieuw,0), '0.#')), '.'), concat('Je bent ', format(eerder, '0.#'), ' jaar eerder hypotheekvrij.')), ' Je bespaart netto ', concat('€ ', format(round(netto_besparing,0), '0.#')), ' rente, een rendement van ', format(rendement, '0.0#'), '% per jaar.', h_bt))
  
• volgende = if(boete_deel > 0, 'Los dit jaar alleen het boetevrije deel af, of reken de boete uit met Boeterente hypotheek berekenen.', 'Vergelijk het rendement met sparen of beleggen via Aflossen of Sparen, en check je nieuwe netto maandlast met Netto maandlasten hypotheek berekenen.')
  

Berekening informatie

Op jouw website?

<script src="https://ikbenbint.nl/widget.js"
  data-berekening="extra-aflossen-hypotheek-berekenen">
</script>